{$CLEO .cs}
{$I includes/VK_KEYS.txt} //includes
//{$include includes/RakNetDefines.txt}

0000: NOP

thread "CarSpawnerManual_by_Karabawka"

// В первой части скрипта читаем память из vehicles.ide , чтобы скрипт узнавал модельки машин.
0AC8: 1@ = allocate_memory_size 32

:carspawn_read_string
wait 0 // ждем 0 мс, для избежания зависаний   
0@ = 400 // Указывает на строчку в файле vehicles.ide   

// Проверки на введение названия модели авто

:carspawn_checking
0ADB: 1@ = car_model 0@ name   
if
0ADC:   test_cheat 1@ // Проверка: если введено название модели авто на клавиатуре.   
else_jump @carspawn_str_num // если не введено, прыгаем на метку str_num
if   
     Car.Defined(5@) // Проверка: если машина создана. То есть игрок уже в какой-то машине. ( Хендл : 5@ )
else_jump @carspawn_model_checking // если не создана, прыгаем на метку carspawn_model_checking
Actor.StorePos($PLAYER_ACTOR, 10@, 11@, 12@) // записывем координаты игрока $PLAYER_ACTOR в переменные X Y Z
0362: remove_actor $PLAYER_ACTOR from_car_and_place_at 10@ 11@ 12@ // Выкидываем игрока $PLAYER_ACTOR из машины на координаты X Y Z, записанные строчкой выше.
Car.Destroy(5@) // удаляем авто c хендлом 5@

// Проверки на существования модели авто
:carspawn_model_checking
wait 0   
if   
     Model.Available(0@)
else_jump @carspawn_model_checking_load   
jump @carspawn // Если существует, прыгаем на метку создания авто carspawn (наша основная часть работы скрипта)

:carspawn_model_checking_load
Model.Load(0@)
jump @carspawn_model_checking
// Конец проверок моделей.

// Создание авто.
:carspawn
Actor.StorePos($PLAYER_ACTOR, 10@, 11@, 12@) // Записываем коордианты игрока $PLAYER_ACTOR в 3 перменные (координаты X Y Z)
5@ = Car.Create(0@, 10@, 11@, 12@) // Создаем тачку с хендлом 5@
Model.Destroy(0@) // Необходимо удалить модель
036A: put_actor $PLAYER_ACTOR in_car 5@ // ТПшим игрока $PLAYER_ACTOR в созданое авто с хендлом 5@
Car.SetImmunities(5@, 1, 1, 1, 1, 1) // Делаем авто неуязвимым (можно убрать это, как хотите)
01EC: make_car 5@ very_heavy 1 // Данный опкод делает наше авто 5@ тяжелым (1 - значение true)
0ACD: "Car spawned, fuck yeah!" 3000 // Данный опкод выводит текст на экран о том, что машина создана, текст выводится в течении 3000 милисекунд = 3 секунды

:carspawn_str_num
0@ += 1   
    0@ > 611   
else_jump @carspawn_checking
jump @carspawn_read_string