{$CLEO .cs}
wait 0
0662: "Tutorial and script code written MISTER_GONWIK."
0662: "The lesson was written June 24, 2012."
0662: "Especially for Cheat-master.ru"
0662: "All rights reserved."

const
actor = $PLAYER_ACTOR
car = 0@
X = 1@
Y = 2@
Z = 3@
object_angle = 4@
object = 2910
object_handle = 5@
z_ground = 6@
actor_angle = 7@
KEY_ACTIVATE_TP = 57
end           

while true  //начало потока
wait 0
model.Load(object)//            загружаем
038B: load_requested_models//   модель 2910      
         if model.Available(object)  // если модель загружена, то идём дальше
         then
             while true
             wait 0
                 if 0ab0: KEY_ACTIVATE_TP // если нажата клавиша 'KEY_ACTIVATE_TP',
                 then                     // то скрипт начинает свою работу
                 repeat
                 wait 0                          // если клавиша 'KEY_ACTIVATE_TP' не отпущена,
                 until 8ab0: not KEY_ACTIVATE_TP // то скрипт не продолжит своё действие (пока клавиша не будет отпущена)
                     if actor.Driving(actor)  // если актёр за рулём
                     then                     // то      
                     03C0: car = actor actor car //записываем хендл машины в 'car'            
                         actor.StorePos(actor X Y Z) //записываем координаты актёра в переменные:'X' 'Y' 'Z'
                         actor_angle = actor.Angle(actor) // записываем угол актёра
                         wait 0              //ждём 0 мс
                         Z = 910.0           // переписываем значение переменной Z (высота) на '910.0'      
                         actor.PutAt(actor X Y Z) //телепортируем актёра с машиной в небо на высоту '910.0'           
                     actor.StorePos(actor X Y Z) //записываем координаты актёра в переменные:'X' 'Y' 'Z'
                     wait 0                  //ждём 0 мс
                     Z -= 2.0                // переписываем значение переменной Z (высота) на '908.0' (то есть 910.0 - 2.0 = 908.0)
                     object.Create(object_handle, object, X Y Z) //создаём объект на координатах 'X' 'Y' 'Z'
                     object_angle = actor.Angle(actor) // разворачиваем объект на угол актёра
                     0750: set_object object_handle visibility 0 //делаем объект невидимым (значение 1 придаст объекту видимый эффект)
                     camera.Restore_WithJumpCut()  // восстанавливаем камеру
                     0175: set_car car Z_angle_to 0.0  // меняем угол машины по оси Z на значение 0.0 (чтобы машины ровно упала на дорогу)
                         repeat                  // ^repeat^
                         wait 0                   //ждём 0 мс
                         actor.StorePos(actor X Y 30@) //записываем координаты актёра в переменные:'X' 'Y' '30@'
                         01BC: put_object object_handle at X Y Z //перемещаем объект под актёра на координаты 'X' 'Y' 'Z'
                         object_angle = actor.Angle(actor) // записываем угол актёра
                         object.Angle(object_handle) = object_angle // разворачиваем объект на угол актёра
                         until 0ab0: KEY_ACTIVATE_TP  // если не нажата клавиша 'KEY_ACTIVATE_TP',то возвращаемся на ^repeat^
                     repeat
                     wait 0                    // если клавиша 'KEY_ACTIVATE_TP' не отпущена,
                     until 8ab0: not KEY_ACTIVATE_TP       // то скрипт не продолжит своё действие (пока клавиша не будет отпущена)
                         object.Destroy(object_handle) //уничтожаем объект
                         actor.StorePos(actor X Y Z) //записываем координаты актёра в переменные:'X' 'Y' 'Z'
                         actor_angle = actor.Angle(actor) // записываем угол актёра
                         actor.PutAt(actor X Y 20.0) //телепортируем актёра с машиной на координаты 'X' 'Y' '20.0'
                         wait 0                   //ждём 0 мс
                         02CE: z_ground = ground_z_at X Y 9999.0 //находим высоту земли на координатах 'X' 'Y' и записываем ее в переменную 'z_ground'      
                         actor.PutAt(actor X Y z_ground) //телепортируем актёра с машиной на координаты 'X' 'Y' 'z_ground'       
                         car.Angle(car) = actor_angle //разворачиваем машину на угол актёра
                         camera.Restore_WithJumpCut()  // восстанавливаем камеру
                     end
                 end
             end
         end
end