{$CLEO .cs}
0000:

if 8AF7: get_samp_base_to 0@
then 0A93: end_custom_thread
end
repeat  
wait 400
until 0AFA: is_samp_structures_available

const // все возможные стили диалогов, взято из a_samp.inc
DIALOG_STYLE_MSGBOX = 0
DIALOG_STYLE_INPUT = 1
DIALOG_STYLE_LIST = 2
DIALOG_STYLE_PASSWORD = 3
end

0AC8: 4@ = allocate_memory_size 128 // выделяем память для хранения форматированной строки

while true
  wait 0
  if 0AB0: key_pressed 0x32 // 2
  then
   0AD3: string 4@ format "Пункт1%cПункт2%cПункт3" 10 10 // разделение пунктов осуществляется таким образом
   0B3B: samp show_dialog id 2 caption "Выберите один из пунктов" text 4@ button_1 "Ок" button_2 "Отмена" style DIALOG_STYLE_LIST
   while 0AB0: key_pressed 0x32
    wait 20
   end
  end
  if 0B3C: samp dialog_respond 0@ button 1@ list_item 2@ input_text 0 // проверим, был ли закрыт любой диалог, созданный этим CLEO
  then
   if 0@ == 2
   then
    if 1@ == 1
    then
     if 2@ == 0
     then
      0B3B: samp show_dialog id 3 caption "Диалог №1" text "Это диалог с идом 3" button_1 "Ок" button_2 "" style DIALOG_STYLE_MSGBOX
     end
     if 2@ == 1
     then
      0B3B: samp show_dialog id 4 caption "Диалог №2" text "Это диалог с идом 4" button_1 "Ок" button_2 "" style DIALOG_STYLE_INPUT
     end
     if 2@ == 2
     then
      0B3B: samp show_dialog id 5 caption "Диалог №3" text "Это диалог с идом 5" button_1 "Ок" button_2 "" style DIALOG_STYLE_LIST
     end
    end
   end
   if 0@ == 3
   then
    0ACD: "~R~Dialog 1" 1000 // сообщение красного цвета
   end
   if 0@ == 4
   then
    0ACD: "~G~Dialog 2" 1000 // сообщение зелёного цвета
   end
   if 0@ == 5
   then
    0ACD: "~B~Dialog 3" 1000 // сообщение синего цвета
   end
   0AF8: samp add_message_to_chat "Диалог с идом %d был закрыт." color 0xFF61B 0@ // сообщим ид закрытого диалога в чат
  end
end