{$CLEO }
{$Include includes\RakNetDefines.txt}

thread "pizdarvanka"
0662: "Example for SAMPFUNCS v2.0"
0662: "Made by FYP"
0662: "ec"

const
KEY_TOGGLE_1 = 80 // P
KEY_TOGGLE_2 = 77 // M

CHEAT_STATE = 1@
PIZ_SPEED = 2@
PIZ_SPEED_CMD = 3@
PIZ_DELAY = 20
end

if not 0@ = SAMP.Base()
then 0A93: end_custom_thread
end

while not SAMP.Available()
     wait 100
end
0B34: samp PIZ_SPEED_CMD = register_client_command "pizspeed"
PIZ_SPEED = 10.0

while true  
     wait 0
     if player.Defined(0)
     jf continue
      
     if and
     0AB0: key_down KEY_TOGGLE_1
     0AB0: key_down KEY_TOGGLE_2
     then  
         0B12: CHEAT_STATE = CHEAT_STATE XOR 1  // toggle cheat
         if CHEAT_STATE == 1
         then 0ACD: print "Pizdarvanka activated." 1000
         else 0ACD: print "Pizdarvanka deactivated." 1000
         end
         while true
             wait 20
             if and
             0AB0: key_down KEY_TOGGLE_1
             0AB0: key_down KEY_TOGGLE_2
             jf break
         end
     end
      
     if 0B35: samp is_command_typed PIZ_SPEED_CMD params 5@
     then
         if 0AD4: 5@ = scan_string 5@ format "%f" 6@ //IF and SET
         then
             if 5@ > 0
             then
                 0087: PIZ_SPEED = 6@
                 0AF8: samp add_message_to_chat "Pizdarvanka speed = %f" color 0xDD00 6@
             end
         else
             0AF8: samp add_message_to_chat "Command syntax: /pizspeed [speed:float]" color 0xDD0000
         end
     end
      
     if and
     not actor.Dead($PLAYER_ACTOR)
     CHEAT_STATE == 1
     jf continue
      
     if actor.Driving($PLAYER_ACTOR)
     then
         03C0: 5@ = actor $PLAYER_ACTOR car
         6@ = car.Angle(5@)
         7@ = SAMP.GetSAMPVehicleIDByCarHandle(5@)
         0C02: math 6@ = angle_to_radian 6@ // (float)
         6@ *= -1.0
         0C03: math 8@ = sine 6@ // (float)
         0C05: math 9@ = cosine 6@ // (float)
         006B: 8@ *= PIZ_SPEED // (float)
         006B: 9@ *= PIZ_SPEED // (float)
         0AB1: call @SendIncarFakeSpeed 4 xyz 8@ 9@ 0.0 vehicleid 7@  
     else
         6@ = Actor.Angle($PLAYER_ACTOR)
         0C02: math 6@ = angle_to_radian 6@ // (float)
         6@ *= -1.0
         0C03: math 8@ = sine 6@ // (float)
         0C05: math 9@ = cosine 6@ // (float)
         006B: 8@ *= PIZ_SPEED // (float)
         006B: 9@ *= PIZ_SPEED // (float)
         0AB1: call @SendOnfootFakeSpeed 3 8@ 9@ 0.0
     end
      
     wait PIZ_DELAY
      
end

const
sizeof_stOnFootData = 68
sizeof_stInCarData = 63
end

// struct stOnFootData  ( size = 68 )
//    uint16_t    sLeftRightKeys;  
//    uint16_t    sUpDownKeys; + 2
//    uint16_t    sKeys; + 4
//    float  fPosition[3]; + 6  
//    float  fQuaternion[4]; + 18
//    uint8_t  byteHealth; + 34
//    uint8_t  byteArmor; + 35
//    uint8_t  byteCurrentWeapon; + 36
//    uint8_t  byteSpecialAction; + 37
//    float  fMoveSpeed[3]; + 38  
//    float  fSurfingOffsets[3]; + 50
//    uint16_t    sSurfingVehicleID; + 62
//    int   iCurrentAnimationID; + 64

:SendOnfootFakeSpeed
// 0@, 1@, 2@ = speed
// Example: 0AB1: call @SendOnfootFakeSpeed 3 xyz 10@ 11@ 12@
3@ = SAMP.GetSAMPPlayerIDByActorHandle($PLAYER_ACTOR)
3@ = SAMP.GetPlayerStruct(3@)
3@ += 613 // local onFootData
0AC8: 4@ = allocate_memory_size sizeof_stOnFootData
call @memcpy 3 destination 4@ source 3@ size sizeof_stOnFootData  // copy original onfoot data to my onfoot data buffer
0085: 5@ = 4@ // (int)  

5@ += 38 // fMoveSpeed[0] ( X )
0A8C: write_memory 5@ size 4 value 0@ virtual_protect 0
5@ += 4 // fMoveSpeed[1] ( Y )
0A8C: write_memory 5@ size 4 value 1@ virtual_protect 0
5@ += 4 // fMoveSpeed[2] ( Z )
0A8C: write_memory 5@ size 4 value 2@ virtual_protect 0

0B3D: raknet 5@ = new_bit_stream

0B40: raknet bit_stream 5@ write PACKET_PLAYER_SYNC type BS_TYPE_BYTE size 1
0B40: raknet bit_stream 5@ write 4@ type BS_TYPE_ARRAY size sizeof_stOnFootData
0B42: raknet send bit_stream 5@ priority PRIORITY_HIGH reliability UNRELIABLE_SEQUENCED ordering_channel 0

0B3E: raknet delete_bit_stream 5@
0AC9: free_allocated_memory 4@

0AB2: ret 0

// struct stInCarData  ( size = 63 )
//    uint16_t    sVehicleID;
//    uint16_t    sLeftRightKeys; + 2
//    uint16_t    sUpDownKeys; + 4
//    uint16_t    sKeys; + 6
//    float  fQuaternion[4]; + 8
//    float  fPosition[3]; + 24
//    float  fMoveSpeed[3]; + 36
//    float  fVehicleHealth; + 48
//    uint8_t  bytePlayerHealth; + 52
//    uint8_t  byteArmor; + 53
//    uint8_t  byteCurrentWeapon; + 54
//    uint8_t  byteSiren; + 55
//    uint8_t  byteLandingGearState; + 56
//    uint16_t    sTrailerID; + 57
//    float  fTrainSpeed; + 59

:SendIncarFakeSpeed
// 0@, 1@, 2@ - speed, 3@ - vehicle id
// Example: 0AB1: call @SendIncarFakeSpeed 4 xyz 10@ 11@ 12@ vehicleid 13@
5@ = SAMP.GetSAMPPlayerIDByActorHandle($PLAYER_ACTOR)
5@ = SAMP.GetPlayerStruct(5@)
5@ += 681 // local inCarData
0AC8: 4@ = allocate_memory_size sizeof_stInCarData
call @memcpy 3 destination 4@ source 5@ size sizeof_stInCarData  // copy original incar data to my incar data buffer
0085: 5@ = 4@ // (int)
   
0A8C: write_memory 5@ size 2 value 3@ virtual_protect 0 // sVehicleID
5@ += 36 // fMoveSpeed[0] ( X )
0A8C: write_memory 5@ size 4 value 0@ virtual_protect 0
5@ += 4 // fMoveSpeed[1] ( Y )
0A8C: write_memory 5@ size 4 value 1@ virtual_protect 0
5@ += 4 // fMoveSpeed[2] ( Z )
0A8C: write_memory 5@ size 4 value 2@ virtual_protect 0

0B3D: raknet 5@ = new_bit_stream

0B40: raknet bit_stream 5@ write PACKET_VEHICLE_SYNC type BS_TYPE_BYTE size 1
0B40: raknet bit_stream 5@ write 4@ type BS_TYPE_ARRAY size sizeof_stInCarData
0B42: raknet send bit_stream 5@ priority PRIORITY_HIGH reliability UNRELIABLE_SEQUENCED ordering_channel 0

0B3E: raknet delete_bit_stream 5@
0AC9: free_allocated_memory 4@

0AB2: ret 0

:memcpy

var
0@ : integer
1@ : integer
2@ : integer
3@ : integer
end

// 0@ - destination, 1@ - source, 2@ - size
// Example: 0AB1: call @memcpy 3 destination 0@ source 1@ size 2@

dec(2@)
for 3@ = 0 to 2@
     0A8D: 4@ = read_memory 1@ size 1 virtual_protect 0
     0A8C: write_memory 0@ size 1 value 4@ virtual_protect 0
     1@ += 1
     0@ += 1
end

0AB2: ret 0