{$CLEO}
const // все возможные стили диалогов, взято из a_samp.inc
DIALOG_STYLE_MSGBOX = 0
DIALOG_STYLE_INPUT = 1
DIALOG_STYLE_LIST = 2
DIALOG_STYLE_PASSWORD = 3
end

while true
wait 0
if 0AB0: key_pressed 0x31 // 1
then
0B3B: samp show_dialog id 2 caption "Пример №1" text "Нажмите "Да", если вам хочется нажать "Да", иначе нажмите "Нет"." button_1 "Да" button_2 "Нет" style DIALOG_STYLE_MSGBOX
while true // бесконечный цикл, пока пользователь не закроет диалог
wait 0

if 0B3C: samp dialog_respond 2 button 1@ list_item 0 input_text 0 // проверим, был ли диалог с идом 2 закрыт и запишем в переменную 1@ ид нажатой кнопки, поскольку остальные параметры нам не нужны, туда можно записать нули
then
if 1@ == 1 // если была нажата левая кнопка
then
0B3B: samp show_dialog id 2 caption "Инфо" text "Вы нажали кнопку "Да"" button_1 "Ок" button_2 "" style DIALOG_STYLE_MSGBOX
else
0B3B: samp show_dialog id 2 caption "Инфо" text "Вы нажали кнопку "Нет"" button_1 "Ок" button_2 "" style DIALOG_STYLE_MSGBOX
end
break
end

while 0AB0: key_pressed 0x31 // на всякий случай подождём, пока пользователь не отпустит клавишу
wait 20
end
end
end

const
sizeof_stOnFootData = 68 // размер структуры информации о игроке пешком
end      

:SendOnfootFakePosition
// 0@, 1@, 2@ = coords
// Example: 0AB1: call @SendOnfootFakePosition 3 xyz 10@ 11@ 12@
3@ = SAMP.GetSAMPPlayerIDByActorHandle($PLAYER_ACTOR)
3@ = SAMP.GetPlayerStruct(3@)
3@ += 109 // получаем указатель на локальную onFootData, чтобы потом её скопировать в наш буффер, изменив в нём только позицию
0AC8: 4@ = allocate_memory_size sizeof_stOnFootData // выделим память для буффера такого же размера, каким является размер структуры данных синхронизации пешком
0AB1: call @memcpy 3 destination 4@ source 3@ size sizeof_stOnFootData  // моя функция побайтового копирования данных одного участка памяти в другой
0085: 5@ = 4@ // нужно чтоб сохранить адрес на начало нашего буффера

5@ += 6 // прибавим оффсет на fPosition[0] ( X ), т.к. нам кроме позиции ничего не нужно
0A8C: write_memory 5@ size 4 value 0@ virtual_protect 0 // запишем новое значение позиции, в переменной 0@ - хранится X (об этом позже)
5@ += 4 // размер типа float составляет 4 байта, а т.к. в массиве все элементы расположены упорядоченно, прибавив 4 байта, мы получим указатель на fPosition[1] ( Y )
0A8C: write_memory 5@ size 4 value 1@ virtual_protect 0 // и запишем новое значение координаты Y
5@ += 4 // fPosition[2] ( Z )
0A8C: write_memory 5@ size 4 value 2@ virtual_protect 0

0B3D: raknet 5@ = new_bit_stream

0B40: raknet bit_stream 5@ write PACKET_PLAYER_SYNC type BS_TYPE_BYTE size 1 // пишем ид пакета, PACKET_PLAYER_SYNC - это синхронизация пешком, тип обязательно должен быть указан BS_TYPE_BYTE
0B40: raknet bit_stream 5@ write 4@ type BS_TYPE_ARRAY size sizeof_stOnFootData // запишем наш буффер в битстрим, т.к. буффер - это массив байтов, укажем тип BS_TYPE_ARRAY и размер, равный размеру буффера
0B42: raknet send bit_stream 5@ priority PRIORITY_HIGH reliability UNRELIABLE_SEQUENCED ordering_channel 0 // отправим всё это на сервер

0B3E: raknet delete_bit_stream 5@ // освобождаем память выделенную под BitStream
0AC9: free_allocated_memory 4@ // освобождаем память выделенную под буффер

0AB2: ret 0 // выходим из функции

:memcpy

var
0@ : integer
1@ : integer
2@ : integer
3@ : integer
end

// 0@ - destination, 1@ - source, 2@ - size
// Example: 0AB1: call @memcpy 3 destination 0@ source 1@ size 2@

dec(2@)
for 3@ = 0 to 2@
     0A8D: 4@ = read_memory 1@ size 1 virtual_protect 0
     0A8C: write_memory 0@ size 1 value 4@ virtual_protect 0
     1@ += 1
     0@ += 1
end

0AB2: ret 0