{$CLEO}
0661: NOP "FermaBot by BoPoH"
0661: NOP "Õîòÿ, âñ¸ ðàâíî êòî-íèáóäü îáÿçàòåëüíî èñïðàâèò êîïèðàéòû :D"
0661: NOP "Èñõîäíèê ïðèëàãàåòñÿ, ïðàâüòå, ñêîëüêî âëåçåò"

20@ = 1 // ôëàã ïåðâîãî ïîèñêà æ¸ëòîãî ìàðêåðà

while not player.Defined($PLAYER_CHAR)
wait 0
end

:Start
while true
wait 0
    if and
    0AB0: 66 // B
    0AB0: 90 // Z
    not actor.Driving($PLAYER_ACTOR)
    then
        20@ = 1
        while 0AB0: 90 // Æä¸ì ïîêà èãðîê îòïóñòèò êíîïêó Z
        wait 0
        end
        0AD1: show_formatted_text_highpriority "FermaBot by BoPoH is activated!~n~Searching for yellow pickup..." time 2000
        // Èùåì æ¸ëòûé ïèêàï
        // Íà ñàìîì äåëå ýòî îáúåêò ñ id 19197
    
        :StartSearching // Íå ëþáëþ èñïîëüçîâàòü ìåòêè, íî òóò áåç íèõ òÿæåëî áóäåò
        while true  // Áóäåì èñêàòü ïèêàï êàæäûé èãðîâîé öèêë
            actor.StorePos($PLAYER_ACTOR, 0@, 1@, 2@)
            0AB1: @GetNearestObjectWithModel 3 pos 0@ 1@ model 19197 handle 3@
            
            if
            03CA:   object 3@ exists
            then
                0AD1: show_formatted_text_highpriority "Yellow pickup found!" time 2000
                break
            end
            
            if
            gosub @CheckIfTurnOff
            then
                jump @Start
            end
            
            if
            actor.Driving($PLAYER_ACTOR)
            then
                0AB1: @EnableActorsCollision 0       
                0687: clear_actor $PLAYER_ACTOR task
                0AD1: show_formatted_text_highpriority "FermaBot by BoPoH is deactivated!" time 2000
                jump @Start
            end
            wait 0
        end
        
        // Èòàê, åñëè ìû âûøëè èç öèêëà, çíà÷èò îáúåêò íàéäåí
        // Îòïðàâèì èãðîêà òóäà
        object.StorePos(3@, 0@, 1@, 2@)
        0687: clear_actor $PLAYER_ACTOR task
        wait 0
        if
        80ED:   not actor $PLAYER_ACTOR 0 near_point 0@ 1@ radius 0.5 0.5 on_foot
        then
            05D3: AS_actor $PLAYER_ACTOR goto_point 0@ 1@ 2@ mode 7 -2 ms
            wait 100
        end
        32@ = 0
        while 80ED:   not actor $PLAYER_ACTOR 0 near_point 0@ 1@ radius 0.5 0.5 on_foot         // áåæèì ê æ¸ëòîìó ìàðêåðó
            wait 0 // Æä¸ì, ïîêà èãðîê äîáåæèò äî ìåñòà íàçíà÷åíèÿ
            0AD1: show_formatted_text_highpriority "We are going to yellow pickup" time 2000
            0AB1: @HasActorGoToTask 1 actor $PLAYER_ACTOR get_to 10@
            //0AD1: show_formatted_text_highpriority "%d" time 2000 10@
            if
            10@ == 0
            then
                05D3: AS_actor $PLAYER_ACTOR goto_point 0@ 1@ 2@ mode 7 -2 ms
            else
                0A8C: write_memory 0xB7345A size 2 value -128 virtual_protect 0 // Ýìóëèðóåì íàæàòèå êëàâèøè W, ÷òîáû äðóãèì áûë âèäåí áåã
            end
            0AB1: @DisableActorsCollision 0
            
            if
            gosub @CheckIfTurnOff
            then
                jump @Start
            end
            
            if
            32@ > 50000
            then
                break
            end
            
            if and  // åñëè ïîèñê íå ïåðâûé, òî ïðîáåæêà äî ìàðêåðà íå çàéì¸ò áîëüøå 5 ñåêóíä
            20@ == 0
            32@ > 5000
            then
                jump @SearchYellowMarker2
            end
        end
        20@ = 0
        
        :SearchMarker   // èùåì êðàñíûé ìàðêåð
        32@ = 0   
        33@ = 0
        while true
            0AB1: @DisableActorsCollision 0
            0AB1: @GetNearestMarker 2 pos 0@ 1@ get_pos 4@ 5@ id 6@
            if
            not 6@ == -1
            then
                0687: clear_actor $PLAYER_ACTOR task
                wait 0
                if
                80ED:   not actor $PLAYER_ACTOR 0 near_point 4@ 5@ radius 1.0 1.0 on_foot
                then
                    05D3: AS_actor $PLAYER_ACTOR goto_point 4@ 5@ 2@ mode 7 -2 ms  
                    wait 100
                end
                while 80ED:   not actor $PLAYER_ACTOR 0 near_point 4@ 5@ radius 2.0 2.0 on_foot
                    wait 0 // Æä¸ì, ïîêà èãðîê äîáåæèò äî ìåñòà íàçíà÷åíèÿ
                    0AD1: show_formatted_text_highpriority "We are going to red marker" time 2000
                    0AB1: @HasActorGoToTask 1 actor $PLAYER_ACTOR get_to 10@
                    //0AD1: show_formatted_text_highpriority "%d" time 2000 10@
                    if
                    10@ == 0
                    then
                        05D3: AS_actor $PLAYER_ACTOR goto_point 4@ 5@ 2@ mode 7 -2 ms
                    else
                        0A8C: write_memory 0xB7345A size 2 value -128 virtual_protect 0 // Ýìóëèðóåì íàæàòèå êëàâèøè W, ÷òîáû äðóãèì áûë âèäåí áåã
                    end
                    0AB1: @DisableActorsCollision 0
                    
                    if
                    gosub @CheckIfTurnOff
                    then
                        jump @Start
                    end
                end
                break   // Ìû äîáðàëèñü äî ìàðêåðà
            else
                if
                33@ > 5000
                then
                    0AB1: @GetNearestObjectWithModel 4 pos 0@ 1@ model 19197 start 3@ handle 4@ // ìàðêåð íå ïîÿâèëñÿ
                    // äåëàåì âûâîä, ÷òî ãðóçîâèê çàïîëíåí
                    // èùåì íîâûé æ¸ëòûé ïèêàï
                    //0AD1: show_formatted_text_highpriority "Searching new yellow pickup! %d %d" time 2000 3@ 4@
                    if
                    03CA:   object 4@ exists
                    then
                        0085: 3@ = 4@ // (int)
                        object.StorePos(3@, 0@, 1@, 2@)
                        20@ = 1
                        jump @SearchYellowMarker2       // åñëè íàøëè íîâûé ïèêàï, èä¸ì ê íåìó
                    end
                end
            end
            
            if
            gosub @CheckIfTurnOff
            then
                jump @Start
            end
            
            if
            32@ > 10000
            then
                break
            end
            wait 0
        end
        
        32@ = 0
        while true
            0AB1: @DisableActorsCollision 0
            0AB1: @MarkerExist 1 6@ get_status 7@
            if
            7@ == 0
            then
                0AD1: show_formatted_text_highpriority "Searching for yellow pickup..." time 2000
                break
            end
            
            if
            gosub @CheckIfTurnOff
            then
                jump @Start
            end
            
            if
            32@ > 25000
            then
                break
            end
            wait 0
        end
        
        if
        gosub @CheckIfTurnOff
        then
            break
        end
        
        :SearchYellowMarker2        // òîïàåì ê æ¸ëòîìó ìàðêåðó
        if
        03CA:   object 3@ exists
        then
            0687: clear_actor $PLAYER_ACTOR task
            wait 0
            if
            80ED:   not actor $PLAYER_ACTOR 0 near_point 0@ 1@ radius 0.5 0.5 on_foot
            then
                05D3: AS_actor $PLAYER_ACTOR goto_point 0@ 1@ 2@ mode 7 -2 ms
                wait 100
            end
            
            32@ = 0
            while 80ED:   not actor $PLAYER_ACTOR 0 near_point 0@ 1@ radius 0.5 0.5 on_foot
                wait 0 // Æä¸ì, ïîêà èãðîê äîáåæèò äî ìåñòà íàçíà÷åíèÿ
                0AD1: show_formatted_text_highpriority "We are going to yellow pickup" time 2000
                0AB1: @HasActorGoToTask 1 actor $PLAYER_ACTOR get_to 10@
                //0AD1: show_formatted_text_highpriority "%d" time 2000 10@
                if
                10@ == 0
                then
                    05D3: AS_actor $PLAYER_ACTOR goto_point 0@ 1@ 2@ mode 7 -2 ms
                else
                    0A8C: write_memory 0xB7345A size 2 value -128 virtual_protect 0 // Ýìóëèðóåì íàæàòèå êëàâèøè W, ÷òîáû äðóãèì áûë âèäåí áåã
                end
                0AB1: @DisableActorsCollision 0
                
                if
                gosub @CheckIfTurnOff
                then
                    jump @Start
                end
                if
                32@ > 20000
                then
                    break
                end
                if and
                20@ == 0
                32@ > 5000
                then
                    jump @SearchYellowMarker2
                end
            end
            jump @SearchMarker
        else
            jump @StartSearching
        end
    end
end

:CheckIfTurnOff
if and
0AB0: 66 // B
0AB0: 90 // Z
then
    while 0AB0: 90 // Z
    wait 0
    end
    0AB1: @EnableActorsCollision 0       
    0687: clear_actor $PLAYER_ACTOR task
    0AD1: show_formatted_text_highpriority "FermaBot by BoPoH is deactivated!" time 2000
    0485:   return_true
else
    if
    8184: not  actor $PLAYER_ACTOR health >= 1
    then
        0AB1: @EnableActorsCollision 0       
        0687: clear_actor $PLAYER_ACTOR task
        0AD1: show_formatted_text_highpriority "FermaBot by BoPoH is deactivated!" time 2000
        0485:   return_true
    else
        059A:   return_false
    end
end
return

:GetNearestMarker
10@ = 0xC7DD58 // Ïóë ìàðêåðîâ

4@ = 0
5@ = 1000.0
for 30@ = 0 to 31
    0085: 29@ = 30@
    29@ *= 0xA0
    29@ += 48
    005A: 29@ += 10@  // (int)
    0A8D: 2@ = read_memory 29@ size 4 virtual_protect 0
    29@ += 4
    0A8D: 3@ = read_memory 29@ size 4 virtual_protect 0
    29@ += 32
    0A8D: 6@ = read_memory 29@ size 4 virtual_protect 0
    0509: 4@ = distance_between_XY 0@ 1@ and_XY 2@ 3@
    
    if and
    not 2@ == 0.0
    not 3@ == 0.0
    0025:   5@ > 4@
    not 6@ == 0
    then
        0087: 5@ = 4@
        0087: 11@ = 2@ // X
        0087: 12@ = 3@ // Y
        0085: 13@ = 30@ // (int)
    end
end

if
5@ < 30.0
then
    0AB2: ret 3 11@ 12@ 13@
else
    0AB2: ret 3 0.0 0.0 -1
end

:MarkerExist
0@ *= 0xA0
0@ += 0xC7DD58
0@ += 0x54
0A8D: 0@ = read_memory 0@ size 4 virtual_protect 0
0AB2: ret 1 0@

:GetNearestObjectWithModel // 0AB1: @GetNearestObjectWithModel 3 pos 0@ 1@ model 19197 handle 3@
0A8D: 10@ = read_memory 0xB7449C size 4 virtual_protect 0 // CObject Pool
0A8D: 11@ = read_memory 10@ size 4 virtual_protect 0 // CObject Array
10@ += 8
0A8D: 12@ = read_memory 10@ size 4 virtual_protect 0 // CObject Number
12@ -= 1

20@ = 0 // Object Handle
25@ = 0 // Object 2 Handle
21@ = 0 // Pos
22@ = 0
23@ = 0
24@ = 1000.0 // Distance

for 4@ = 0 to 12@
    0085: 5@ = 4@
    5@ *= 0x19C
    5@ += 0x18
    005A: 5@ += 11@
    0A8D: 6@ = read_memory 5@ size 4 virtual_protect 0 // RwObject
    if
    6@ > 0
    then
        5@ -= 0x18
        0AEC: 7@ = object_struct 5@ handle
        if
        09CC:   object 7@ model_is 2@
        then
            object.StorePos(7@, 21@, 22@, 23@)
            0509: 8@ = distance_between_XY 0@ 1@ and_XY 21@ 22@
            if
            0025: 24@ > 8@
            then
                if
                803B: not 7@ == 3@  // (int)
                then
                    0085: 20@ = 7@
                    0087: 24@ = 8@
                end
            end
        end
    end
end

if
24@ < 100.0
then
0AB2: ret 1 20@
else
0AB2: ret 1 -1
end

:DisableActorsCollision
actor.StorePos($PLAYER_ACTOR, 0@, 1@, 2@)
0A8D: 10@ = read_memory 0xB74490 size 4 virtual_protect 0 // CPed Pool
0A8D: 11@ = read_memory 10@ size 4 virtual_protect 0 // CPed Array
10@ += 8
0A8D: 12@ = read_memory 10@ size 4 virtual_protect 0 // CPed Number
12@ -= 1

8@ = 0
for 4@ = 0 to 12@
    0085: 5@ = 4@
    5@ *= 0x7C4
    5@ += 0x18
    005A: 5@ += 11@
    0A8D: 6@ = read_memory 5@ size 4 virtual_protect 0 // RwObject
    if
    6@ > 0
    then
        5@ -= 0x18
        0AEA: 7@ = actor_struct 5@ handle
        actor.StorePos(7@, 20@, 21@, 22@)
        050A: 17@ = distance_between_XYZ 0@ 1@ 2@ and_XYZ 20@ 21@ 22@
        if and
        87D6: not 7@ == $PLAYER_ACTOR
        17@ < 20.0
        80DF: not actor 7@ driving
        then
            0619: enable_actor 7@ collision_detection 0
            8@ += 1
        end
    end
end
//0AD1: show_formatted_text_highpriority "%d" time 2000 8@
0AB2: ret 0

:EnableActorsCollision
actor.StorePos($PLAYER_ACTOR, 0@, 1@, 2@)
0A8D: 10@ = read_memory 0xB74490 size 4 virtual_protect 0 // CPed Pool
0A8D: 11@ = read_memory 10@ size 4 virtual_protect 0 // CPed Array
10@ += 8
0A8D: 12@ = read_memory 10@ size 4 virtual_protect 0 // CPed Number
12@ -= 1

for 4@ = 0 to 12@
    0085: 5@ = 4@
    5@ *= 0x7C4
    5@ += 0x18
    005A: 5@ += 11@
    0A8D: 6@ = read_memory 5@ size 4 virtual_protect 0 // RwObject
    if
    6@ > 0
    then
        5@ -= 0x18
        0AEA: 7@ = actor_struct 5@ handle
        actor.StorePos(7@, 20@, 21@, 22@)
        if and
        87D6: not 7@ == $PLAYER_ACTOR
        80DF: not actor 7@ driving
        then
            0619: enable_actor 7@ collision_detection 1
        end
    end
end
0AB2: ret 0

:HasActorGoToTask // 0AB1: @HasActorGoToTask 1 actor $PLAYER_ACTOR get_to 0@
0A96: 1@ = actor 0@ struct
1@ += 0x47C
0A8D: 2@ = read_memory 1@ size 4 virtual_protect 0
if
2@ > 0
then
    2@ += 4
    for 3@ = 0 to 4
        0085: 4@ = 2@ // (int)
        0085: 5@ = 3@ // (int)
        5@ *= 4
        005A: 4@ += 5@  // (int)
        0A8D: 6@ = read_memory 4@ size 4 virtual_protect 0
        if
        6@ > 0
        then
            0A8D: 7@ = read_memory 6@ size 4 virtual_protect 0
            7@ += 0x10
            0A8D: 8@ = read_memory 7@ size 4 virtual_protect 0
            0AA7: call_function 8@ num_params 0 pop 0 get_id 9@
            if
            9@ == 0x387
            then
                0AB2: ret 1 1
            end
        end

    end
end
0AB2: ret 1 0